blob: a1a9450a3e80b0ca4a9ee8235988b744664f4fa6 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
|
; "record.scm" record data types
; Written by David Carlton, carlton@husc.harvard.edu.
; Re-Written by Aubrey Jaffer, jaffer@ai.mit.edu, 1996, 1997
;
; This code is in the public domain.
; Implements `record' data structures for Scheme. Using only the
; opacity of procedures, makes record datatypes and
; record-type-descriptors disjoint from R4RS types and each other, and
; prevents forgery and corruption (modification without using
; RECORD-MODIFIER) of records.
(require 'common-list-functions)
(define vector? vector?)
(define vector-ref vector-ref)
(define vector-set! vector-set!)
(define vector-fill! vector-fill!)
(define vector->list vector->list)
(define display display)
(define write write)
(define record-modifier #f)
(define record-accessor #f)
(define record-constructor #f)
(define record-predicate #f)
(define make-record-type #f)
(let (;; Need to close these to keep magic-cookie hidden.
(make-vector make-vector)
(vector vector)
;; We have to wrap these to keep magic-cookie hidden.
(vect? vector?)
(vect-ref vector-ref)
(vect->list vector->list)
(disp display)
(wri write)
;; Need to wrap these to protect record data from being corrupted.
(vect-set! vector-set!)
(vect-fill! vector-fill!)
(nvt "of non-vector type")
)
(letrec
(;; Tag to identify rtd's. (A record is identified by the rtd
;; that begins it.)
(magic-cookie (cons 'rtd '()))
(rtd? (lambda (object)
(and (vect? object)
(not (= (vector-length object) 0))
(eq? (rtd-tag object) magic-cookie))))
(rec? (lambda (obj)
(and (vect? obj)
(>= (vector-length obj) 1)
(or (eq? magic-cookie (rec-rtd obj))
(rtd? (rec-rtd obj))))))
(vec:error
(lambda (proc-name msg obj)
(slib:error proc-name msg
(cond ((rtd? obj) 'rtd)
((rec? obj) (rtd-name (rec-rtd obj)))
(else obj)))))
;; Internal accessor functions. No error checking.
(rtd-tag (lambda (x) (vect-ref x 0)))
(rtd-name (lambda (rtd) (if (vector? rtd) (vect-ref rtd 1) "rtd")))
(rtd-fields (lambda (rtd) (vect-ref rtd 3)))
;; rtd-vfields is padded out to the length of the vector, which is 1
;; more than the number of fields
(rtd-vfields (lambda (rtd) (cons #f (rtd-fields rtd))))
;; rtd-length is the length of the vector.
(rtd-length (lambda (rtd) (vect-ref rtd 4)))
(rec-rtd (lambda (x) (vect-ref x 0)))
(rec-disp-str
(lambda (x)
(let ((name (rtd-name (rec-rtd x))))
(string-append
"#<" (if (symbol? name) (symbol->string name) name) ">"))))
(make-rec-type
(lambda (type-name field-names)
(if (not (or (symbol? type-name) (string? type-name)))
(slib:error 'make-record-type "non-string type-name argument."
type-name))
(if (or (and (list? field-names) (comlist:has-duplicates? field-names))
(comlist:notevery symbol? field-names))
(slib:error 'make-record-type "illegal field-names argument."
field-names))
(let* ((augmented-length (+ 1 (length field-names)))
(rtd (vector magic-cookie
type-name
'()
field-names
augmented-length
#f
#f)))
(vect-set! rtd 5
(lambda (x)
(and (vect? x)
(= (vector-length x) augmented-length)
(eq? (rec-rtd x) rtd))))
(vect-set! rtd 6
(lambda (x)
(and (vect? x)
(>= (vector-length x) augmented-length)
(eq? (rec-rtd x) rtd)
#t)))
rtd)))
(rec-predicate
(lambda (rtd)
(if (not (rtd? rtd))
(slib:error 'record-predicate "invalid argument." rtd))
(vect-ref rtd 5)))
(rec-constructor
(lambda (rtd . field-names)
(if (not (rtd? rtd))
(slib:error 'record-constructor "illegal rtd argument." rtd))
(if (or (null? field-names)
(equal? field-names (rtd-fields rtd)))
(let ((rec-length (- (rtd-length rtd) 1)))
(lambda elts
(if (= (length elts) rec-length) #t
(slib:error 'record-constructor
(rtd-name rtd)
"wrong number of arguments."))
(apply vector rtd elts)))
(let ((rec-vfields (rtd-vfields rtd))
(corrected-rec-length (rtd-length rtd))
(field-names (car field-names)))
(if (or (and (list? field-names) (comlist:has-duplicates? field-names))
(comlist:notevery (lambda (x) (memq x rec-vfields))
field-names))
(slib:error
'record-constructor "invalid field-names argument."
(cdr rec-vfields)))
(let ((field-length (length field-names))
(offsets
(map (lambda (field) (comlist:position field rec-vfields))
field-names)))
(lambda elts
(if (= (length elts) field-length) #t
(slib:error 'record-constructor
(rtd-name rtd)
"wrong number of arguments."))
(let ((result (make-vector corrected-rec-length)))
(vect-set! result 0 rtd)
(for-each (lambda (offset elt)
(vect-set! result offset elt))
offsets
elts)
result)))))))
(rec-accessor
(lambda (rtd field-name)
(if (not (rtd? rtd))
(slib:error 'record-accessor "invalid rtd argument." rtd))
(let ((index (comlist:position field-name (rtd-vfields rtd)))
(augmented-length (rtd-length rtd)))
(if (not index)
(slib:error 'record-accessor "invalid field-name argument."
field-name))
(lambda (x)
(if (and (vect? x)
(>= (vector-length x) augmented-length)
(eq? rtd (rec-rtd x)))
#t
(slib:error 'record-accessor "wrong record type." x "not" rtd))
(vect-ref x index)))))
(rec-modifier
(lambda (rtd field-name)
(if (not (rtd? rtd))
(slib:error 'record-modifier "invalid rtd argument." rtd))
(let ((index (comlist:position field-name (rtd-vfields rtd)))
(augmented-length (rtd-length rtd)))
(if (not index)
(slib:error 'record-modifier "invalid field-name argument."
field-name))
(lambda (x y)
(if (and (vect? x)
(>= (vector-length x) augmented-length)
(eq? rtd (rec-rtd x)))
#t
(slib:error 'record-modifier "wrong record type." x "not" rtd))
(vect-set! x index y)))))
)
(set! vector? (lambda (obj) (and (not (rec? obj)) (vect? obj))))
(set! vector-ref
(lambda (vector k)
(cond ((rec? vector)
(vec:error 'vector-ref nvt vector))
(else (vect-ref vector k)))))
(set! vector->list
(lambda (vector)
(cond ((rec? vector)
(vec:error 'vector->list nvt vector))
(else (vect->list vector)))))
(set! vector-set!
(lambda (vector k obj)
(cond ((rec? vector)
(vec:error 'vector-set! nvt vector))
(else (vect-set! vector k obj)))))
(set! vector-fill!
(lambda (vector fill)
(cond ((rec? vector)
(vec:error 'vector-fill! nvt vector))
(else (vect-fill! vector fill)))))
(set! display
(lambda (obj . opt)
(apply disp (if (rec? obj) (rec-disp-str obj) obj) opt)))
(set! write
(lambda (obj . opt)
(if (rec? obj)
(apply disp (rec-disp-str obj) opt)
(apply wri obj opt))))
(set! record-modifier rec-modifier)
(set! record-accessor rec-accessor)
(set! record-constructor rec-constructor)
(set! record-predicate rec-predicate)
(set! make-record-type make-rec-type)
))
|
